VBA, MS Access MS Access в примерах

Создание свойства БД для хранения неких данных

По материалам: http://www.cyberforum.ru/ms-access/thread2493768-page2.html

Пример обращения на чтение - запись


    CurrentDb.Properties("Dayhist") = "Значение"


Процедура создания свойства:

Private Sub CreateDayhist()
'mobile - 24.08.2019
'Создание свойства БД для хранения неких данных, тут текст "Dayhist"
'По материалам: http://www.cyberforum.ru/ms-access/thread2493768-page2.html
'----------------------------------------------------------------
Dim prp As Property, db As DAO.Database
Const sPrpName$ = "Dayhist" 'Название свойства
 
On Error GoTo CreateDayhist_Err
 
    Set db = CurrentDb
    Set prp = db.CreateProperty(sPrpName, dbText, " ")
    
    db.Properties.Append prp
 
CreateDayhist_End:
    On Error Resume Next
    Err.Clear
    Exit Sub
 
CreateDayhist_Err:
    If Err.Number = 3367 Then
        'MsgBox "Свойство с названием [" & sPrpName & "] уже существует.", vbInformation
    Else
        MsgBox "Error " & Err.Number & " (" & Err.Description & ") in Sub CreateDayhist.", _
            vbCritical, "Произошла ошибка!"
    End If
    Err.Clear
    Resume CreateDayhist_End
 
End Sub



В форме например:

Private Sub btnClear_Click()
'Кнопка : Очистка
    CurrentDb.Properties("Dayhist") = " "
    Me.hist = " "
End Sub

Private Sub FIO_AfterUpdate()
'После изменения поля
    Me.hist = Me.FIO & " " & Me.hist
    CurrentDb.Properties("Dayhist") = Me.hist
End Sub

Private Sub Form_Load()
'На загрузке формы
    Me.hist = CurrentDb.Properties("Dayhist")
End Sub

Назад ToTop
L.E. 24.08.2019
Рейтинг@Mail.ru