Возраст на конкретную или текущую дату с точностью до месяца и дня (текстом)

Public Function AgeByBirthDayStr(bdDate As Variant, Optional forDate As Variant = Null) As String
'Возвращает возраст на текущую дату (или на конкретную дату) с точностью до месяца и дня (текстом)
' При ошибке вернёт текст с её номером ...
'--------------------------------------------------------------------------
'Аргументы:
'   bdDate      -  Дата Рождения
'   forDate     -  Дата на которую рассчитать (по умолчанию = сегодня)
'--------------------------------------------------------------------------
' ?AgeByBirthDayStr (#12/12/1476#)
' Вернёт: Лет: 542 Мес: 2 Дней: 22 - столько живут только вампиры и вурдалаки (вроде меня)
'--------------------------------------------------------------------------
Dim dLastBDay As Date
Dim iYears%, iMonthes%, iDays%, i%

On Error GoTo AgeByBirthDayErr

'Проверяем аргументы
    If IsNull(forDate) Then forDate = Date

'Разница в годах между датой рождения и датой на которую
    iYears = DateDiff("yyyy", bdDate, forDate)

    dLastBDay = DateSerial(Year(forDate), Month(bdDate), Day(bdDate))

'Вычитается один год, если в этом году дня рождения еще не было
    If dLastBDay > forDate Then
        iYears = iYears - 1
    End If
    
    i = Year(bdDate) + iYears
    dLastBDay = DateSerial(i, Month(bdDate), Day(bdDate))
    'Debug.Print "LastBDay: " & dLastBDay

'Меяцев
    iMonthes = DateDiff("m", dLastBDay, forDate)
    If Day(bdDate) > Day(forDate) Then
        iMonthes = iMonthes - 1
    End If

'Дней
    dLastBDay = DateSerial(i, Month(bdDate) + iMonthes, Day(bdDate))
    iDays = DateDiff("d", dLastBDay, forDate)

'Результат:
    AgeByBirthDayStr = "Лет: " & iYears
    AgeByBirthDayStr = AgeByBirthDayStr & " Мес: " & iMonthes
    AgeByBirthDayStr = AgeByBirthDayStr & " Дней: " & iDays
    
AgeByBirthDayBye:
    Exit Function

AgeByBirthDayErr:
    AgeByBirthDayStr = "Err!:" & Err.Number
    'MsgBox "Error: " & Err.Number & vbCrLf & Err.Description & vbCrLf & _
        "in Function: AgeByBirthDayStr ", vbCritical, "Error in Application"

    Err.Clear
    Resume AgeByBirthDayBye
End Function