FSO - Получение подробной информации о файле (FSO.File)

Private Sub FSO_FileInfo_Demo() 
' Получение подробной информации о файле (FSO)
' s0000547 - 04.02.2024 v002
' Подробности: https://script-coding.com/WSH/FileSystemObject.html
' -------------------------------------------------------------------------------------------------/
Dim objFSO As Object, objFSOFile As Object, sVal$, sExtensionName$
Dim lSizeB As Long, cSizeKB As Currency, cSizeMB As Currency
    
    sVal = CurrentProject.FullName ' тек. БД

    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFSOFile = objFSO.GetFile(sVal)
    sExtensionName = objFSO.GetExtensionName(sVal) 'Расширение отдельно
    
'Размер:
    lSizeB = objFSOFile.Size
    cSizeKB = lSizeB / 1024
    cSizeMB = cSizeKB / 1024
    
    sVal = vbNullString
    sVal = sVal & "Дата время создания: " & objFSOFile.DateCreated & vbCrLf
    sVal = sVal & "Дата время последнего доступа: " & objFSOFile.DateLastAccessed & vbCrLf
    sVal = sVal & "Дата время последней модификации: " & objFSOFile.DateLastModified & vbCrLf
    sVal = sVal & "Диск: " & objFSOFile.Drive.DriveLetter & vbCrLf
    
    sVal = sVal & "Имя: " & objFSOFile.Name & vbCrLf
    sVal = sVal & "Родительский каталог: " & objFSOFile.ParentFolder.Path & vbCrLf
    sVal = sVal & "Путь: " & objFSOFile.Path & vbCrLf
    sVal = sVal & "Короткое имя: " & objFSOFile.ShortName & vbCrLf
    sVal = sVal & "Путь в формате 8.3: " & objFSOFile.ShortPath & vbCrLf
    sVal = sVal & "Тип файла - " & objFSOFile.Type & vbCrLf
    sVal = sVal & "Расширение: *." & sExtensionName & vbCrLf
    sVal = sVal & "Размер: " & lSizeB & " байт" & _
        " : " & Format(cSizeKB, "0.0") & "Кb" & _
        " : " & Format(cSizeMB, "0.0") & "Mb" & vbCrLf
    sVal = sVal & String(80, "-") & vbCrLf
    
    Set objFSO = Nothing
    Set objFSOFile = Nothing

    Debug.Print sVal 'Вывод в Immediate Window

End Sub