Подключение указанной таблицы определённого MDB файла (DAO)

Public Function esConnectTableMDB(sBasePath As String, _
                srsTblName As String, _
                Optional newTblName As String = "", _
                Optional MakeHidden As Boolean = False) As Long
'es 30.06.2011
'Подключение указанной таблицы MDB файла
'--------------------------------------------------------------------
'Аргументы:
'   sBasePath     = Строка пути вида: "C:\Temp\MyDB.mdb"
'   srsTblName    = Исходное название таблицы в базе
'   newTblName    = Новое имя таблицы (по умолч. = srsTblName)
'   makeHidden    = Сделать скрытой (по умолч. = нет)
'При ошибке возвращает ее код
'--------------------------------------------------------------------
Dim db As DAO.Database
Dim tdf As DAO.TableDef
    
'Имя создаваемой таблицы
    If newTblName = "" Then newTblName = srsTblName
'Удаление старой (если есть)
On Error Resume Next
    Set db = CurrentDb
    db.TableDefs.Delete newTblName
    Err.Clear
'Создание и подключение
On Error GoTo ConnectToTableErr
    Set tdf = db.CreateTableDef(newTblName)
    tdf.Connect = ";DATABASE=" & sBasePath
    tdf.SourceTableName = srsTblName
    db.TableDefs.Append tdf

'Если указано что должна быть скрытая
    If MakeHidden = True Then tdf.Attributes = dbHiddenObject

ConnectToTableBye:
    On Error Resume Next
    Set tdf = Nothing
    db.Close
    Set db = Nothing
    Exit Function

ConnectToTableErr:
    esConnectTableMDB = Err.Number
    'Debug.Print Err.Description
    Resume ConnectToTableBye
End Function